insert-sort of a buffer in gen codebox ?

OK so the idea is that you have two input buffers A and B, and you want to fill a third buffer C with some mix of A and B. The buffers can be different lengths, but you want both of them to be effectively stretched to fit the length of C.

So I'd want to go through the length of C sample by sample, call that index. We'll use that to poke to buffer C. I want to do it sample by sample to make sure every single slot in C is filled. For each one I'd derive phase as index/dim(C), and use that phase to do an interpolated phase-based lookup into A and B (via the sample operator), and blend the two values and poke them into C.

The easiest way to start is to do it as a sample-by-sample process. (We can always wrap that into a for loop later to process a bit faster if it is feasible.) That just means making index be a History, and incrementing it by 1 on each sample:

Buffer A, B, C;
Param blend(0.5, min=0, max=1);
History index;

if (index < dim(C)) {
	phase = index/dim(C); // 0..1
	// read the two input buffers at this phase:
	a = sample(A, phase);
	b = sample(B, phase);
	// mix them and write into C at current index:
	s = mix(a, b, blend);
	poke(C, s, index);
	
	index += 1; // move to next sample
}

This also has to happen over the channels of the buffers. I'd loop through the channels that exist in C, and use those to select channels from A and B according to some @channelmode option, probably @channelmode wrap, so that it still works even if A and B have different numbers of channels.

Also it would probably be handy to output a signal to say when it is done:

Buffer A, B, C;
Param blend(0.5, min=0, max=1);
History index;

busy = index < dim(C);
if (index < dim(C)) {
	phase = index/dim(C); // 0..1
	// for each output channel:
	for (c=0; c<channels(C); c+=1) {
		// read the two input buffers at this phase:
		a = sample(A, phase, c, channelmode="wrap");
		b = sample(B, phase, c, channelmode="wrap");
		// mix them and write into C at current index:
		s = mix(a, b, blend);
		poke(C, s, index, c);
	}
	index += 1; // move to next sample
}
out1 = (index >= dim(C)); // output 1 when done. 

That works, but to fill a 1 second buffer~ C it will take 1 second of time. You might want to do things a bit faster. Let's say we want to allow up to 100 writes per sample. Then we can loop this process 100/channels(C) times.

Buffer A, B, C;
Param blend(0.5, min=0, max=1);
History index;

// how much can we advance per sample?
numloops = ceil(100/channels(C));

for (i=0; (i < numloops) && (index < dim(C)); i+=1) {	
	phase = index/dim(C); // 0..1
	// for each output channel:
	for (c=0; c<channels(C); c+=1) {
		// read the two input buffers at this phase:
		a = sample(A, phase, c, channelmode="wrap");
		b = sample(B, phase, c, channelmode="wrap");
		// mix them and write into C at current index:
		s = mix(a, b, blend);
		poke(C, s, index, c);
	}
	index += 1; // move to next sample
}

out1 = (index >= dim(C)); // output 1 when done.